;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; PROCEDURE: delta_tb
; PURPOSE: returns the differential brightness temperature as a 
;          function of density, temperature, and redshift
; INPUTS:
;          tk -- kinetic temperature in kelvin
;          z -- redshift
;          nHI -- HI number density in cm^-3
; OUTPUT:
;          dt -- differential brightness temperature in mK for
;                collisional excitation only
;          highdt -- differential brightness temperature in high
;                    spin temperature limit
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

function delta_tb, nHI, tk, z, FULLYCOUPLED=fullycoupled

omegamh2=0.147 ; DEPENDENCE OF dtb ON HUBBLE PARAMETER

tcmb=2.726*(1.+z)
tkl=alog10(tk)

highdt=1.14e5*(omegamh2/0.147)^(-0.5)*((1.+z)/11.)^(-2.5)*nhI
if keyword_set(fullycoupled) then return, highdt

nt = N_elements(tk)
yconhl = fltarr(nt)
yconhl[*] = 0.5206

ind = where(tkl gt 0.)
if ind[0] ge 0 then yconhl[ind]=0.5206-0.419*tkl[ind]+1.272*tkl[ind]^2+0.4760*tkl[ind]^3
ind = where(tkl gt 1.)
if ind[0] ge 0 then yconhl[ind]=-4.134+9.781*tkl[ind]- $
                                4.7755*tkl[ind]^2+1.075*tkl[ind]^3-0.091*tkl[ind]^4

yc=10.^yconhl * nhI
ts=(tcmb+yc*tk)/(1.+yc)
;dt = highdt*(1.-tcmb/ts)
return, highdt*(1.-tcmb/ts)
end